@echo off
:: Укажите название игры.
:: Используйте пустое значение, для автоопределения.
::-----------------------------------------------
:: Мой выбор: по-умолчанию.
set game=
:: Укажите каталог файлов с игрой.
:: Может быть абсолютный или относительный путь.
:: Не используйте кавычки здесь!
::-----------------------------------------------
:: Мой выбор:
set game_dir=D:\media\games\bAC
:: Укажите маски файлов для экспорта.
:: Возможно добавлять другие расширений здесь.
::-----------------------------------------------
:: Мой выбор: по-умолчанию.
set file_mask=*.u* *.xxx
:: Укажите параметры совместимости такие, как
:: -sounds -3rdparty -nomesh -noanim -nostat -notex -lzo -lzx -zlib
::-----------------------------------------------
:: Мой выбор:
set compat=-3rdparty -sounds
:: Другие опции umodel
::-----------------------------------------------
:: Мой выбор:
set options=-export -uncook -uc
:: Каталог контента экспорта.
:: Может быть абсолютный или относительный путь.
:: Не используйте кавычки здесь!
::-----------------------------------------------
:: Мой выбор:
set out=__export_bAC
:: Запись работы в журнал. Лог-файл umodel
::-----------------------------------------------
:: Мой выбор:
set log=%out%\__log_Export.txt
:: Путь umodel.exe
::-----------------------------------------------
:: Мой выбор:
set umodel=d:\bin\umodel.exe
::-----------------------------------------------
:: Конец блока настройки.
:: --
:: End of settings block
::-----------------------------------------------
:: Debug
::set umodel=echo umodel
:: Prepare some options
if not "%game%" == "" set game_opt=-game=%game%
if not "%out%" == "" set out_opt=-out="%out%"
if "%file_mask%" == "" set file_mask=*.*
if not "%game_dir%" == "" (
set path_opt=-path="%game_dir%"
if not exist "%game_dir%" (
echo ERROR: game directory "%game_dir%" is not valid
exit
)
)
:: export from the current directory by default
if "%game_dir%" == "" set game_dir=.
if not "%log%" == "" (
set log_opt=-log="%log%"
if exist "%log%" del %log%
)
:: Process ...
for /r "%game_dir%" %%a in (%file_mask%) do call :process "%%a"
goto :eof
::-----------------------------------------------
:: Function to process single package
::-----------------------------------------------
:process
echo Processing %1 ...
%umodel% %path_opt% %options% %compat% %game_opt% %out_opt% %log_opt% %1
[/spoiler]
Author